Ansicht
Dokumentation

05753 - CL FOR ENTIRE SYSTEM.

05753 - CL FOR ENTIRE SYSTEM.

Addresses (Business Address Services)   ROGBILLS - Synchronize billing plans  
This documentation is copyright by SAP AG.
SAP E-Book

CL FOR ENTIRE SYSTEM.

Hi Rubens,
this is my solution for the full system-backup that we do every night.
Additonally we do a SAVSYS after applying OS patches (DB fix-pack, cumtapes,
ptfs).

Hope this helps.
Kind regards
Karl

==========================================================================

AR3CL002
/*********************************************************************/

/* PROGRAMMFUNKTION.: Control ROGRAMM sav R/3 */

/* PROGRAMMIERER....: GRAUER */

/* ERSTELLDATUM.....: 23.12.97 */

/* LETZTE AENDERUNG.: */

/* */

/*********************************************************************/

PGM PARM(&WSATPS &WSATTS)

DCL &WSATPS *CHAR 1 /* J=ATP SYSTEM STARTEN */

DCL &MSG *CHAR 132 /* MSG-TEXT ERSTNACHR. */

/*---- ALLE DURCHBRUCHNACHRICHTEN AUF PGM-EBENE UEBERWACHEN ---------*/

MONMSG MSGID(CPF9999) EXEC(GOTO SNDMSG)

CHGJOB LOG(3 11) LOGCLPGM(*YES)

/*---- END R/3 PRODUKTIONSSYSTEM --------------------------------*/
CALL PGM(AR3CL003) PARM('E' 'ATP' '02')

/*---- execute save DATENSICHERUNG -------------------------------------*/

CALL AR3CL004
/*---- START R/3 PRODUKTIONSSYSTEM -------------------------------*/
IF COND(&WSATPS *EQ 'J') THEN(DO)
CALL PGM(AR3CL003) PARM('S' 'ATP' '02')
ENDDO
/*---- SYSTEMMELDUNGEN ABFRAGEN -------------------------------------*/
SNDMSG: RCVMSG MSG(&MSG)
IF COND(&MSG = ' ') THEN(GOTO CMDLBL(ENDE))
SNDPGMMSG MSG(&MSG) TOPGMQ(*PRV)
GOTO SNDMSG
/*---- PROGRAMMENDE -------------------------------------------------*/
ENDE: ENDPGM



========================================================================


AR3CL003
/*********************************************************************/
/* PROGRAMMFUNKTION.: START/STOP R/3-SYSTEM */
/* Attention!!!!!!!!!!!!! */
/* before changing this program call */
/* CALL R3ATP400/R3INLPGM */
/* */
/* PROGRAMMIERER....: GRAUER */
/* ERSTELLDATUM.....: 22.12.97 */
/* LETZTE AENDERUNG.: */
/* 22.02.2000/GRAUER - DELAY 120 EINGEBAUT, WEIL BEI PWRDWNSYS */
/* TCP/IP NOCH NICHT AKTIV */
/* */
/*********************************************************************/
PGM PARM(&ART &SID &INST)

DCL &ART *CHAR 1 /* ART S=START E=STOP
*/
DCL &SID *CHAR 3 /* SYSTEM-ID
*/
DCL &INST *CHAR 2 /* INSTANZ-NR.
*/
DCL &LIB *CHAR 10 /* BIBLIOTHEKSNR.
*/
DCL &MSG *CHAR 132 /* MSG-TEXT ERSTNACHR.
*/
/*---- ALLE DURCHBRUCHNACHRICHTEN AUF PGM-EBENE UEBERWACHEN ---------*/
MONMSG MSGID(CPF9999) EXEC(GOTO SNDMSG)

/*---- SET library list ---------------------------------------*/
CHGVAR VAR(&LIB) VALUE('R3' *CAT &SID *CAT '400')

CALL &LIB/R3INLPGM

/*-------------------------------------------------------------------*/
/*---- START R/3 -------------------------------------------------*/
/*-------------------------------------------------------------------*/
IF COND(&ART = 'S') THEN(DO)
DLYJOB DLY(120)
STARTSAP SID(&SID) INSTANCE(&INST) DLTSPLF(*NO)
DLYJOB DLY(120)
ENDDO
/*-------------------------------------------------------------------*/
/*---- STOP R/3 SYSTEM -------------------------------------------*/
/*-------------------------------------------------------------------*/
IF COND(&ART = 'E') THEN(DO)
/*---- STOP OS-COLLECTOR -----------------------------------------*/
CALL SAPOSCOL PARM('-k')
DLYJOB DLY(60)
/*---- STOP R/3 --------------------------------------------------*/
STOPSAP SID(&SID) INSTANCE(&INST)
DLYJOB DLY(300)
ENDDO
/*-------------------------------------------------------------------*/
/*---- SYSTEMMELDUNGEN ABFRAGEN -------------------------------------*/
/*-------------------------------------------------------------------*/
SNDMSG: RCVMSG MSG(&MSG)
IF COND(&MSG = ' ') THEN(GOTO CMDLBL(ENDE))
SNDPGMMSG MSG(&MSG) TOPGMQ(*PRV)
GOTO SNDMSG
/*---- PROGRAMMENDE -------------------------------------------------*/
ENDE: ENDPGM


=========================================================================

AR3CL004
/********************************************************************/
/* PROGRAMMFUNKTION.: daily save */
/* PROGRAMMIERER....: GRAUER */
/* ERSTELLDATUM.....: 09.04.87 */
/********************************************************************/
PGM
DCL &MSG *CHAR 132 /* MSG-TEXT ERSTNACHR. */
DCL &MSGID *CHAR 7 /* MSGID */
DCL &SW *DEC 1 /* KZ CPF9999 BER.AKTIV */
DCL &SW1 *DEC 1 /* KZ CPF9999 AKTIV */
DCL &TAP *CHAR 10 /* NAME TAPE-DEVICE */
DCL &ANTWORT *CHAR 1
DCL &MSGRPY *CHAR 1 /* MSG-ANTWORT */
/*---- ALLE DURCHBRUCHNACHRICHTEN AUF PGM-EBENE UEBERWACHEN --------*/
MONMSG MSGID(CPF9999) EXEC(GOTO ENDE10)
CHGVAR VAR(&TAP) VALUE('TAP02')
/*---- Tape check ---------------------------------------*/
VRYCFG CFGOBJ(&TAP ) CFGTYPE(*DEV) STATUS(*ON)
MONMSG MSGID(CPF0000)
/*---- init tape -------------------------------*/
INZTAP DEV(&TAP ) NEWVOL(ATE050) CHECK(*NO) +
DENSITY(*CTGTYPE)
MONMSG MSGID(CPF6708 CPF6718 CPF6702) EXEC(GOTO +
CMDLBL(SNDMSG))
/*---- TERMINATE SUBSYSTEME ----------------------------------------*/
ENDTCP OPTION(*IMMED)
MONMSG MSGID(CPF0000)
DLYJOB DLY(180)
ENDSBS SBS(QSNADS) OPTION(*IMMED)
MONMSG MSGID(CPF0000)
ENDSBS SBS(QSERVER) OPTION(*IMMED)
MONMSG MSGID(CPF0000)
ENDSBS SBS(QSVCDRCTR) OPTION(*IMMED)
MONMSG MSGID(CPF0000)
ENDSBS SBS(Q1PGSCH) OPTION(*IMMED)
MONMSG MSGID(CPF0000)
ENDSBS SBS(Q1ABRMNET) OPTION(*IMMED)
MONMSG MSGID(CPF0000)
VRYCFG CFGOBJ(ATE3HN) CFGTYPE(*DEV) STATUS(*OFF)
MONMSG MSGID(CPF0000)
VRYCFG CFGOBJ(ATE3HN) CFGTYPE(*CTL) STATUS(*OFF)
MONMSG MSGID(CPF0000)
ENDSBS SBS(QSOC) OPTION(*IMMED)
MONMSG MSGID(CPF0000)
/*---- WARTEN 1 MIN. -----------------------------------------------*/
DLYJOB DLY(60)
/*---- Save security data -------------------------------------*/
SAVSECDTA DEV(&TAP ) SEQNBR(1) ENDOPT(*LEAVE) +
DTACPR(*DEV) COMPACT(*DEV)
MONMSG MSGID(CPF0000)
SAVCFG DEV(&TAP ) SEQNBR(*END) ENDOPT(*LEAVE) +
DTACPR(*DEV) COMPACT(*DEV)
MONMSG MSGID(CPF0000)
/*---- Save IBM PROGRAMMPRODUKTE ---------------------------------*/
SAVLIB LIB(*IBM) DEV(&TAP ) VOL(*MOUNTED) +
SEQNBR(*END) ENDOPT(*LEAVE) CLEAR(*ALL) +
PRECHK(*NO) ACCPTH(*YES) DTACPR(*DEV) +
COMPACT(*DEV)
MONMSG MSGID(CPF0000)
/*---- change JOURNAL-receiver ------------------------------------*/
CHGJRN JRN(ATEDAT/QSQJRN) JRNRCV(*GEN)
MONMSG CPF0000
CHGJRN JRN(R3ATPDATA/QSQJRN) JRNRCV(*GEN)
MONMSG CPF0000
/*---- JOURNALEMPFAENGER SICHERN -------------------------------------*/
SAVOBJ OBJ(QSQJRN*) LIB(ATEDAT) DEV(&TAP ) +
OBJTYPE(*JRNRCV) SEQNBR(*END) ENDOPT(*LEAVE)
MONMSG CPF0000
SAVOBJ OBJ(QSQJRN*) LIB(R3ATPJRN) DEV(&TAP ) +
OBJTYPE(*JRNRCV) SEQNBR(*END) ENDOPT(*LEAVE)
MONMSG CPF0000
/*---- ALLE GESICHERTEN JOURNALEMPFAENGER LOESCHEN -----------------*/
DLTJRNRCV JRNRCV(ATEDAT/QSQJRN*) DLTOPT(*IGNINQMSG)
MONMSG MSGID(CPF0000)
DLTJRNRCV JRNRCV(R3ATPJRN/QSQJRN*) DLTOPT(*IGNINQMSG)
MONMSG MSGID(CPF0000)
/*---- SAVDOC -------------------------------------------------------*/
SAVDLO DLO(*ALL) DEV(&TAP ) VOL(*MOUNTED) +
SEQNBR(*END) ENDOPT(*LEAVE) CLEAR(*ALL)
MONMSG MSGID(CPF0000)
/*---- SAVLIB -------------------------------------------------------*/
SAVLIB LIB(*ALLUSR) DEV(&TAP ) VOL(*MOUNTED) +
SEQNBR(*END) ENDOPT(*LEAVE) CLEAR(*ALL) +
PRECHK(*NO) ACCPTH(*YES) DTACPR(*DEV) +
COMPACT(*DEV)
MONMSG MSGID(CPF0000)
/*---- save IFS --------------------------------------------------*/
SAV DEV('QSYS.LIB/TAP02.DEVD') OBJ(('/*') +
('QSYS.LIB' *OMIT) ('/QDLS' *OMIT)) +
SUBTREE(*ALL) ENDOPT(*UNLOAD)
MONMSG CPF0000
/*---- START SUBSYSTEME -------------------------------------------*/
ENDE10:
STRSBS SBSD(QSERVER)
MONMSG MSGID(CPF0000)
STRSBS SBSD(QSNADS)
MONMSG MSGID(CPF0000)
STRSBS SBSD(QSVCDRCTR/QSVCDRCTR)
MONMSG MSGID(CPF0000)
STRSBS SBSD(QMPGLIB/Q1PGSCH)
MONMSG MSGID(CPF0000)
STRSBS SBSD(QSOC/QSOC)
MONMSG MSGID(CPF0000)
DLYJOB DLY(180)
STRTCP
MONMSG MSGID(CPF0000)
DLYJOB DLY(360)
VRYCFG CFGOBJ(ATE3HN) CFGTYPE(*CTL) STATUS(*ON)
MONMSG MSGID(CPF0000)
VRYCFG CFGOBJ(ATE3HN) CFGTYPE(*DEV) STATUS(*ON)
MONMSG MSGID(CPF0000)
/*---- PGM-NACHRICHTEN AN AUFRUFENDES PGM SENDEN --------------------*/
SNDMSG: RCVMSG MSG(&MSG) MSGID(&MSGID)
IF COND(&MSG = ' ') THEN(RETURN)
SNDPGMMSG MSG(&MSG) TOMSGQ(*LIBL/QSYSOPR) MSGTYPE(*INFO)
GOTO SNDMSG
/*---- PROGRAMMENDE -------------------------------------------------*/
ENDE: ENDPGM


Karl Grauer
Amphenol-Tuchel Electronics
August-Haeusser-Str. 10
DE 74080 Heilbronn
phone: +49 7131/929327
mailto:karl.grauerZa...

www.amphenol.com




-----Ursprüngliche Nachricht-----
Von: Rubens Amorim [mailto:amorimZh...]
Gesendet: Mittwoch, 17. April 2002 12:21
An: DoNotReply@consolut.eu
Betreff: CL FOR ENTIRE SYSTEM.

Hello for all,

I would like to know if anybody has a CL program to do the entire
system(backup).

Tkanks for all,

Best Regards,

Amorim Rubens



Have a look to our homepage at: http://www.consolut.net
DoNotReply@consolut.eu

Your use of consolut is subject to http://www.consolut.net


Durban Tours - Südafrika Safari

Fill RESBD Structure from EBP Component Structure   rdisp/max_wprun_time - Maximum work process run time  
This documentation is copyright by SAP AG.

Length: 10756 Date: 20240302 Time: 122112     sap01-206 ( 2 ms )